mirror of
https://github.com/flatpak/flatpak.git
synced 2026-05-11 01:16:24 -04:00
1293a6441b
* fdio: Avoid relying on VLAs or gcc-specific constant-folding * errors: Fix URL to an old libgsystem commit * lockfile: Assert non-null path in make_lock_file for analyzers * backports: Add g_clear_fd * glnx-errors.h: add glnx_fd_throw[_*] variants * fdio: Add glnx_fd_reopen * local-alloc: Remove duplicate definition of glnx_unref_object * fdio: Add glnx_statx * chase: Add glnx_chaseat which functions similar to openat2 * chase: Add glnx_chase_and_statxat Signed-off-by: Simon McVittie <smcv@collabora.com>
60 lines
1.1 KiB
Meson
60 lines
1.1 KiB
Meson
# Copyright 2019 Endless OS Foundation LLC
|
|
# Copyright 2019 Collabora Ltd.
|
|
# SPDX-License-Identifier: LGPL-2.1-or-later
|
|
|
|
libglnx_testlib = static_library(
|
|
'glnx-testlib',
|
|
'libglnx-testlib.c',
|
|
'libglnx-testlib.h',
|
|
dependencies : [
|
|
libglnx_dep,
|
|
libglnx_deps,
|
|
],
|
|
install : false,
|
|
)
|
|
libglnx_testlib_dep = declare_dependency(
|
|
dependencies : [
|
|
libglnx_dep,
|
|
libglnx_deps,
|
|
],
|
|
include_directories : include_directories('.'),
|
|
link_with : libglnx_testlib,
|
|
)
|
|
|
|
if get_option('tests')
|
|
testing_helper = executable(
|
|
'testing-helper',
|
|
'testing-helper.c',
|
|
dependencies : [
|
|
libglnx_dep,
|
|
libglnx_deps,
|
|
],
|
|
install : false,
|
|
)
|
|
|
|
test_names = [
|
|
'backports',
|
|
'chase',
|
|
'errors',
|
|
'fdio',
|
|
'macros',
|
|
'shutil',
|
|
'testing',
|
|
'xattrs',
|
|
]
|
|
|
|
foreach test_name : test_names
|
|
exe = executable(test_name,
|
|
[
|
|
'test-libglnx-' + test_name + '.c',
|
|
],
|
|
dependencies: [
|
|
libglnx_dep,
|
|
libglnx_deps,
|
|
libglnx_testlib_dep,
|
|
],
|
|
)
|
|
test(test_name, exe, depends: testing_helper)
|
|
endforeach
|
|
endif
|